cnc-club.ru

Код: Выделить всё

/*  10.12.2015 0:50  //G:\PROJECTS\0037_PlanetCNC_mk1
 * Преобразование сигнала от контроллера planet-cnc для управления шпинделем в PWM
 * Подключение пин №2 как вход от planet-cnc (INT0)
 *             пин №3 как выход PWM
 */

volatile unsigned long firstPulseTime;
volatile unsigned long lastPulseTime;
volatile unsigned long numPulses;

void isr()
{
  unsigned long now = micros();
  if (numPulses == 0)
  {
    firstPulseTime = now;
  }
  else
  {
    lastPulseTime = now;
  }
  ++numPulses;
}

void setup()
{
  pinMode(3, OUTPUT);
   
  TCCR2A = _BV(COM2A1) | _BV(COM2B1) | _BV(WGM21) | _BV(WGM20);
  TCCR2B = TCCR2B & 0b11111000 | 0x01;
  OCR2A = 180;
  OCR2B = 1;
}

unsigned int readFrequency(unsigned int sampleTime)
{
  numPulses = 0;                      
  attachInterrupt(0, isr, RISING);   
  delay(sampleTime);
  detachInterrupt(0);
  return (numPulses < 2) ? 0 : (1000000UL * (numPulses - 1))/(lastPulseTime - firstPulseTime);
}

void loop()
{
  unsigned int freq = readFrequency(1000);
  OCR2B = freq;
  delay(10); 
}